Subversion Repositories spacemission

unit SXlib;

//Simplified X handling routine

interface

{$INCLUDE DelphiXcfg.inc}

uses

  Windows, Messages, SysUtils, Classes, Graphics, Controls, Forms,

  {$IFDEF QDA_SUPPORT}QDArc,{$ENDIF}

  DXDraws, DirectX, D3DUtils, DXClass;

(* SXF形式について

    name   | ofs          | length                  | comment

----------------------------------------------------------------------------------------------------

 Signature |            0 |                      16 | 'Simplified_X01  '

 nVextices |           16 |                       2 | number of vertices

 nIndices  |           18 |                       2 | number of indices for vertices

 dwFVF     |           20 |                       4 | flags for flexible vertex format

 VertexSize|           24 |                       4 | required bytes per vertex

 Vertices  |          256 |  VertexSize * nVertices | vertices

 Indices   | 256+Vertices |           2 * nIndices  | indices for vertices

 *)

(* SX形式について(古い)

    name   | ofs          | length         | comment

----------------------------------------------------------------------------

 Signature |            0 |             16 | 'Simplified_X00  '

 nVextices |           16 |              2 | number of vertices

 nIndices  |           18 |              2 | number of indices for vertices

 Vertices  |          256 | 40 * nVertices | vertices(TSXVertex)

 Indices   | 256+Vertices |  2 * nIndices  | indices for vertices

*)

const

//SXファイル識別子

//SX file identifier

  SX_SIGNATURE: string[16] = 'Simplified_X00  '; //SXFlexible

  SXF_SIGNATURE: string[16] = 'Simplified_X01  '; //古いSX

//メッシュを描画するときに一度にDirect3Dに流し込む頂点の最大数(必ず3の倍数)

//One at a time when drawing the flow into the maximum number of vertices Direct3D mesh (must be a multiple of 3)

  DIV_VERTICES: Word = $FFFF;

//TSXVertex用、FVFフラグ

  FVF_SXVERTEX: DWord = (D3DFVF_VERTEX or D3DFVF_DIFFUSE or D3DFVF_SPECULAR);

//TSXVertexMT用

  FVF_SXVERTEXMT: DWord = (D3DFVF_XYZ or D3DFVF_NORMAL or D3DFVF_DIFFUSE or D3DFVF_SPECULAR or D3DFVF_TEX2);

type

  TSXMesh = class;

  TSXFrame = class;

  TSXFrameList = class;

  TSXScene = class;                                                        

  TSXRenderingQueue = class;

//SX形式のための頂点データ

//Vertex data for the SX-style

  TSXVertex = packed record

    case Integer of

      0: (

        x, y, z: Single; //頂点

        nx, ny, nz: Single; //法線

        diffuse: TD3DCOLOR; //ディフューズ

        specular: TD3DCOLOR; //スペキュラ

        tu, tv: Single; //テクスチャ座標 ** Texture coordinates

        );

      1: (

        pos: TD3DVector;

        normal: TD3DVector;

        );

  end;

  PSXVertex = ^TSXVertex;

  TSXVertexArray = array[0..$FFFFFF] of TSXVertex;

  PSXVertexArray = ^TSXVertexArray;

//マルチテクスチャ対応SXVertex

//SXVertex multi-texture support

  TSXVertexMT = packed record

    case Integer of

      0: (

        x, y, z: Single; //頂点

        nx, ny, nz: Single; //法線

        diffuse: TD3DCOLOR; //ディフューズ

        specular: TD3DCOLOR; //スペキュラ

        tu0, tv0: Single; //テクスチャ座標

        tu1, tv1: Single; //テクスチャ座標(2)

        );

      1: (

        pos: TD3DVector;

        normal: TD3DVector;

        );

  end;

  PSXVertexMT = ^TSXVertexMT;

  TSXVertexArrayMT = array[0..$FFFFFF] of TSXVertexMT;

  PSXVertexArrayMT = ^TSXVertexArrayMT;

//ビルボードのための頂点情報

//Billboard top information for

  TSXVertexBB = record

    case Integer of

      0: (

        //視点からの距離1の時の、中心からの相対座標

        //At a distance from the viewpoint of the relative coordinate from the center

        dx, dy: Single;

        color: TD3DCOLOR; //色

        tu, tv: Single; //テクスチャ座標

        );

      1: (

        size: TSngPoint;

        );

  end;

//イベントハンドラ

//Event handler

  TSXRenderMeshEvent = procedure(Sender: TSXFrame) of object;

//ブレンドモード

//Blend

//  TSXBlendMode = (

//    sxbDefault, //普通、透けない

//    sxbAdd, //加算合成

//    sxbAlpha, //半透明

//    sxbSub //減算合成

//    );

//可視属性

//Visible attribute

  TSXVisibility = (

    sxvShow, //見える

    sxvHide, //隠れる。子フレームも含めて

    sxvHideMyself //隠れる。子フレームは隠れない。

    );

//クラス群

//Classes

//メッシュ用クラス

//The Mesh Class

  TSXMesh = class

  private

    procedure SetVertexSize(const Value: DWord);

  protected

    FOwner: TDXDraw; //色々お世話になるDDDDオブジェクト

    FVBuf: IDirect3DVertexBuffer7; //VertexBuffer

    FIndexCount: Word; //頂点インデクスの数

    FVertexCount: Word; //頂点の数

    FFaceCount: Word; //面の数、常に頂点数/3

    FVertexSize: DWord; //１個の頂点あたりのサイズ

    FVFFlags: DWord; //描画させるときのフラグ

    VertexKeepBuf: Pointer; //頂点の配列を入れる。Keep用のバッファとして使う

    FIndices: array of Word; //頂点インデクス

    FLocked: Boolean; //ロック中？

    FPVertex: Pointer; //頂点バッファへのポインタ

    FRecovery: Boolean; //リカバリ中？

    function GetIndex(idx: Word): Word;

    function GetVertex(idx: Word): Pointer;

    procedure SetIndex(idx: Word; const Value: Word);

    procedure SetVertex(idx: Word; const Value: Pointer);

  public

    constructor Create(AOwner: TDXDraw);

    destructor Destroy; override;

    procedure KeepVB; //画面が初期化される時の事を考えて、現在のVBの状態を保持

    procedure RecoverVB; //保持したVBを復元

    property VertexBuffer: IDirect3DVertexBuffer7 read FVBuf; //VertexBuffer

    property IndexCount: Word read FIndexCount; //頂点インデクスの数

    property VertexCount: Word read FVertexCount; //頂点の数

    property FaceCount: Word read FFaceCount; //面の数(頂点の数 / 3

    property Vertex[idx: Word]: Pointer read GetVertex write SetVertex; //頂点への参照

    property Index[idx: Word]: Word read GetIndex write SetIndex; //頂点インデクス

    property FVF: DWord read FVFFlags write FVFFlags; //FlexibleVertexFormatに関するフラグ

    property VertexSize: DWord read FVertexSize write SetVertexSize;

    procedure Draw(dwFlags: DWord); //DrawIndexedPrimitiveVBで全部描画

    procedure DrawPartial(start: Word; count: Word; dwFlags: DWord); //DrawIndexedPrimitiveVBで部分描画

    procedure LoadFromStream(s: TStream);

    procedure LoadFromFile(fileName: string);

    {$IFDEF QDA_SUPPORT}

    procedure LoadFromQDA(QDAName, QDAID: string);

    {$ENDIF}

    function Lock: Pointer;

    procedure Unlock;

    procedure SetSize(newVertexCount, newIndexCount: Word); //バッファの大きさを再設定する、中身は消える

    procedure Optimize;

  end;

{

TSXMesh = class(TSXGenMesh)

  private

    function GetVertex(idx: Word): TSXVertex;  override;

    procedure SetVertex(idx: Word; const Value: TSXVertex); override;

  public

    property Vertex[idx:Word]:TSXVertex read GetVertex write SetVertex; //頂点

    function  Lock:PSXVertexArray;

end;

}

//フレーム

//The Frame

  TSXFrame = class

  private

    FMatrix: TD3DMATRIX; //変換行列(自分の座標系→親座標系)

    FMeshMatrix: TD3DMATRIX; //メッシュ描画時の変換行列…メッシュ座標→自分座標

    FAncestors: TSXFrameList; //祖先フレーム達

    FChildren: TSXFrameList; //子フレーム達

    FParent: TSXFrame; //親フレーム(Ancestors[Ancestors.Count-1]と同)

    FVisibility: TSXVisibility; //可視属性

    FBindRenderState: Boolean; //自分の子孫のレンダリングステートを、強制的に自分のにする

    FBindTexture: Boolean; //自分の子孫のテクスチャを、強制的に自分のにする

    FBindMaterial: Boolean; //自分の子孫のマテリアルを、強制的に自分のにする

    RenderedMatrix: TD3DMATRIX; //最後にレンダリングされたときのワールド行列(ビルボードの描画に使用)

    BBAttached: Boolean; //ビルボードがくっついてる？

    function GetWorldMatrix: TD3DMATRIX;

    procedure SetParent(const Value: TSXFrame);

  public

    //中身

    Texture: TDirect3DTexture2; //メッシュに貼り付けるテクスチャ

    Mesh: TSXMesh; //書き込むメッシュ

    Material: TD3DMATERIAL7; //マテリアル

    //レンダリングステートの制御

    Lighting: Boolean; //True:ライティングをする, False:頂点の色をそのまま使う

    Specular: Boolean; //スペキュラハイライトをつける

    BlendMode: TRenderType; //描画時のブレンドモード

    //イベントハンドラ

    OnRenderMesh: TSXRenderMeshEvent; //メッシュをこれから書きますですイベント

    //いろいろ

    Tag: DWord; //整数値、なんにでも使って

    RenderAttr: Integer; //整数値、OnRenderMeshで、マテリアル番号代わりにどうぞ

    //コンストラクタ・デストラクタ

    constructor Create(parentFrame: TSXFrame);

    destructor Destroy; override;

    //親子関係

    property Ancestors: TSXFrameList read FAncestors;

    property Children: TSXFrameList read FChildren;

    property Parent: TSXFrame read FParent write SetParent;

    property BindRenderState: Boolean read FBindRenderState write FBindRenderState;

    property BindTexture: Boolean read FBindTexture write FBindTexture;

    property BindMaterial: Boolean read FBindMaterial write FBindMaterial;

    //可視属性

    property Visibility: TSXVisibility read FVisibility write FVisibility;

    //座標変換関係

    property Matrix: TD3DMATRIX read FMatrix write FMatrix;

    property WorldMatrix: TD3DMATRIX read GetWorldMatrix; //自分座標→ワールド座標の変換行列

    property MeshMatrix: TD3DMATRIX read FMeshMatrix write FMeshMatrix; //メッシュ描画時の変換行列…メッシュ座標→自分座標

    procedure SetTransform(ref: TSXFrame; const mat: TD3DMATRIX);

    function GetTransform(ref: TSXFrame): TD3DMATRIX;

    function LocalToWorld(vec: TD3DVector): TD3DVector; //フレーム内での座標を、ワールド座標に変換する

    function WorldToLocal(vec: TD3DVector): TD3DVector; //ワールド座標内の座標をフレーム内の座標に変換する

    //位置

    procedure SetTranslation(ref: TSXFrame; const pos: TD3Dvector);

    function GetTranslation(ref: TSXFrame): TD3DVector;

    //姿勢

    //…軸ベクトルで設定・取得

    procedure SetOrientation(ref: TSXFrame; const vecZ: TD3DVector; const vecY: TD3DVector);

    procedure GetOrientation(ref: TSXFrame; var vecZ: TD3DVector; var vecY: TD3DVector);

    //…マトリクスを与えて姿勢だけ設定

    procedure SetOrientationMatrix(ref: TSXFrame; const mat: TD3DMATRIX);

    //お便利

    //…Z軸をtargetフレーム内の座標posを向ける。Y軸はworldフレーム内のY軸に向け。Y軸の傾きをbank度とする

    procedure LookAt(target: TSXFrame; const pos: TD3DVector; world: TSXFrame; const bank: Integer);

    function ViewMatrix: TD3DMatrix; //このフレームをカメラにした場合のビュー行列を生成

  end;

//フレームのリスト

//List of frames

  TSXFrameList = class(TList)

  private

    function GetFrame(idx: Integer): TSXFrame;

    procedure SetFrame(idx: Integer; const Value: TSXFrame);

  public

    property Frames[idx: Integer]: TSXFrame read GetFrame write SetFrame; default;

    constructor Create;

    destructor Destroy; override;

    procedure Assign(source: TSXFrameList);

  end;

//シーン全体

  TSXScene = class

  private

    FCamera: TSXFrame;

    FOwner: TDXDraw;

    FProjectionMatrix: TD3DMATRIX;

    FVP: TD3DVIEWPORT7;

    OpaqueQueue: TSXRenderingQueue; //不透明体用のキュー

    AlphaQueue: TSXRenderingQueue; //半透明透明体用のキュー

    AddQueue: TSXRenderingQueue; //加算半透明体用のキュー

    SubQueue: TSXRenderingQueue; //減算半透明体用のキュー

    //ProcessVertices用

    //MeshProcessor:TSXMesh;          //Lightingをしないとき・環境マップする時用

    //MeshProcessorMT:TSXMesh;        //同上、ただしマルチテクスチャ(2ステージ)版

  public

    constructor Create(DDCompo: TDXDraw);

    destructor Destroy; override;

    property CameraFrame: TSXFrame read FCamera write FCamera; //視点を置くフレーム

    procedure Render(rootFrame: TSXFrame); //rootFrame以下を描画

    procedure Clear(dwFlags: DWord; color: DWORD; z: Single; stencil: DWord); //バックバッファのクリア

    procedure SetProjection(fov, aspect, nearZ, farZ: Single); //透視変換の設定

    procedure SetViewPort(left, top, right, bottom: DWord); //ビューポート

    procedure Recover; //ビューポートなどの状態をリストア

    procedure PushBillboard(blendMode: TRenderType; ref: TSXFrame; pos: TD3DVector; points: array of TSXVertexBB; tex: TDirect3DTexture2);

    function SphereVisibility(ref: TSXFrame; pos: TD3DVector; radius: Single; depth: Single): Boolean; //refフレーム内にある、中心pos、半径radiusの球は見えるか、但し、距離がdepth以上なら見えないものとする

  end;

//ライト

  TSXLight = class

  private

    FOwner: TDXDraw;

    FIndex: DWord; //SetLightに渡す、インデクス

    FEnabled: Boolean;

    FUpdate: Boolean; //パラメータの変更を、即反映

    procedure SetEnabled(const Value: Boolean);

  public

    Params: TD3DLIGHT7;

    constructor Create(DDCompo: TDXDraw; index: DWord);

    destructor Destroy; override;

    procedure BeginUpdate; //Paramsの内容を、Direct3Dに伝えなくする

    procedure EndUpdate; //Paramsの内容を、Direct3Dに伝えなくした状態を解除

    property Enabled: Boolean read FEnabled write SetEnabled;

    //お便利ルーチン

    procedure SetupDiffuse(_R, _G, _B: Single);

    procedure SetupSpecular(_R, _G, _B: Single);

    procedure SetupAmbient(_R, _G, _B: Single);

    procedure SetupColors(difR, difG, difB, specR, specG, specB, ambR, ambG, ambB: Single);

    procedure SetupRanges(range, att0, att1, att2: Single);

    procedure SetupDirectional(dir: TD3DVector);

    procedure SetupPoint(pos: TD3DVector);

    procedure SetupSpot(pos, dir: TD3DVector; theta, phi, falloff: Single);

    procedure FitFrame(target: TSXFrame); //フレームの位置・向きにセットする

  end;

//複数のライトを管理するオブジェクト

  TSXLightGroup = class(TList)

  private

    FOwner: TDXDraw;

    FCapacity: DWord; //管理するライトの数

    FLights: array of TSXLight;

    //FSpecularPower:Single;                                   //スペキュラ強度

    function GetLights(idx: DWord): TSXLight;

    function GetUnusedLight: TSXLight;

//    procedure SetSpecularPower(const Value: Single);

  public

    constructor Create(DDCompo: TDXDraw; capacity: DWord);

    destructor Destroy; override;

    property Lights[idx: DWord]: TSXLight read GetLights; default;

    property UnusedLight: TSXLight read GetUnusedLight; //Enabledになってない、最初のライトを返す

    //property SpecularPower:Single read FSpecularPower write SetSpecularPower;

    procedure EnableAll; //全部点ける

    procedure DisableAll; //全部消す

    procedure Recover; //解像度を変えた後などのリカバリ

  end;

  TSXMaterial = class

  private

    FOwner: TDXDraw;

    FUpdate: Boolean;

  public

    Params: TD3DMATERIAL7;

    constructor Create(DDCompo: TDXDraw);

    procedure BeginUpdate; //Paramsの内容を、Direct3Dに伝えなくする

    procedure EndUpdate; //Paramsの内容を、Direct3Dに伝えなくした状態を解除

    procedure SetupDiffuse(_R, _G, _B: Single);

    procedure SetupSpecular(_R, _G, _B: Single);

    procedure SetupAmbient(_R, _G, _B: Single);

    procedure SetupEmissive(_R, _G, _B: Single);

    procedure SetupSpecularPower(pow: Single);

    procedure SetupColors(difR, difG, difB, specR, specG, specB, ambR, ambG, ambB, emsR, emsG, emsB, pow: Single);

  end;

//メッシュ描画キューに入れる情報

  TSXMeshInfo = record

    frame: TSXFrame; //そのメッシュを描こうとしたフレームはどれ？

    mesh: TSXMesh; //メッシュ

    mat: TD3DMatrix; //変換行列

    tex: TDirect3DTexture2; //テクスチャ

    mtrl: TD3DMATERIAL7; //マテリアル

    lighting: Boolean; //光源計算する/しない

    OnRender: TSXRenderMeshEvent;

  end;

//ビルボード描画キューに入れる情報

  TSXBillboardInfo = record

    ref: TSXFrame; //基準フレーム

    pos: TD3DVector; //基準フレーム内での位置

    tex: TDirect3DTexture2; //テクスチャ

    pts: array[0..3] of TSXVertexBB; //頂点データ

  end;

//レンダリングの順序を保つためのバッファ、透明体かそうでないかで順序を変える。

//Render order to maintain the buffer, or not change the order in a transparent body.

  TSXRenderingQueue = class

  private

    FOwner: TDXDraw; //色々お世話になるDDDDオブジェクト

    Scene: TSXScene; //この

    MeshQueue: array of TSXMeshInfo;

    BillboardQueue: array of TSXBillboardInfo;

    FMeshCapacity: Integer; //メッシュを情報蓄える容量

    FBillboardCapacity: Integer;

    FMeshCount: Integer; //キューに入ってる数

    FBillboardCount: Integer;

    procedure SetBillBoardCapacity(const Value: Integer);

    procedure SetMeshCapacity(const Value: Integer); //ビルボードについての情報を蓄える容量

  public

    constructor Create(AOwner: TDXDraw; _Scene: TSXScene);

    destructor Destroy; override;

    procedure PushMesh(mesh: TSXMesh; frame: TSXFrame; mat: TD3DMatrix; tex: TDirect3DTexture2; mtrl: TD3DMATERIAL7; event: TSXRenderMeshEvent); //メッシュ

    procedure PushBillboard(ref: TSXFrame; pos: TD3DVector; tex: TDirect3DTexture2; pts: array of TSXVertexBB); //ビルボード

    procedure Render(viewMat: TD3DMATRIX; viewParam: TD3DVIEWPORT7); //レンダリング

    procedure Flush; //レンダリングせず、バッファの中を空に     **Without rendering the buffer to empty

    property MeshCapacity: Integer read FMeshCapacity write SetMeshCapacity;

    property BillboardCapacity: Integer read FBillboardCapacity write SetBillBoardCapacity;

    property MeshCount: Integer read FMeshCount;

    property BillboardCount: Integer read FBillboardCount;

  end;

  {Renderer of the primitive}

  TSXPrimitiveRec = packed record

    Texture: TDirect3DTexture2; //テクスチャ

    Bound: array[0..3] of TD3DTLVertex; //四角形

    ZOrder: Integer; //Zオーダ

    BlendMode: TRenderType; //ブレンドモード

  end;

  PPrimitive = ^TSXPrimitiveRec;

  TSXTextureCoordRec = packed record

    Texture: TDirect3DTexture2;

    Top, Left, Bottom, Right: Single; //テクスチャ座標

  end;

  PTextureCoord = ^TSXTextureCoordRec;

  TSingleRect = packed record

    Left, Top, Right, Bottom: Single;

  end;

  TSXPrimitiveRenderer = class

  private

    FDXDraw: TDXDraw;

    FZMax: Integer; //Zオーダの最大値

    FMaxPrimitives: Integer; //格納できるTLVの最大値

    ZSortBuf: ^Integer; //Zソート用バッファ

    ZSortCount: ^Integer; //Zソート用カウンタ

    PrimBuf: PPrimitive; //プリミティブ入れ

    PrimCount: Integer; //現在PrimBufに入ってるプリミティブの数

    Patterns: PTextureCoord; //テクスチャパターン

    FNPrims: Integer; //最後にUpdateメソッドを発行した際の、プリミティブの数

    FColorKey: Boolean; //カラーキーによる抜き色を行う？

    procedure setZMax(v: Integer);

  public

    constructor Create(DDCompo: TDXDraw; PrimitiveCount: Integer; PatternCount: Integer);

    destructor Destroy; override;

    property ZMax: Integer read FZMax write setZMax;

    procedure SetPattern(idx: Integer; Tex: TDirect3DTexture2; Coord: TRect); //パターンとしてTexのCoordで示される範囲を登録

    procedure Push(Tex: TDirect3DTexture2; p1, p2, p3, p4: TD3DTLVertex; Z: Integer; blend: TRenderType); //TLVertexで四角形を入れる

    procedure Push2D(Tex: TDirect3DTexture2; p1, p2, p3, p4: TD2DVector; Z: Integer; blend: TRenderType; col: DWord); //2D的な四角形

    procedure PushPattern(iPat: Integer; p1, p2, p3, p4: TD3DHVector; Z: Integer; blend: TRenderType; col: DWord); //パターンをプッシュ(3次元)

    procedure PushPattern2D(iPat: Integer; p1, p2, p3, p4: TD2DVector; Z: Integer; blend: TRenderType; col: DWord); //パターンをプッシュする

    procedure PushPatternRect(iPat: Integer; rect: TSingleRect; Z: Integer; blend: TRenderType; col: DWord); //パターンをプッシュする(矩形)

    procedure BeginRender; //Z値にしたがってソート

    procedure RenderOneLayer(Z: Integer); //単一のZ値を持つ集合だけ描画

    procedure EndRender; //スタックを空に

    procedure Render; //全部描画(BeginRender～RenderOneLayer～EndRender)

    property nPrims: Integer read FNPrims;

    property ColorKey: Boolean read FColorKey write FColorKey;

    class function SingleRect(x1, y1, x2, y2: Single): TSingleRect;

  end;

//SXVertex作成

function SXVertex(x, y, z, nx, ny, nz: Single; dif, spec: TD3DCOLOR; tu, tv: Single): TSXVertex;

//SXVertexBB作成

function SXVertexBB(dx, dy: Single; col: TD3DCOLOR; tu, tv: Single): TSXVertexBB;

//マテリアル設定の便宜を図る関数

//Convenience function for setting material

function MakeMaterial(difR, difG, difB, specR, specG, specB, ambR, ambG, ambB, emsR, emsG, emsB, pow: Single): TD3DMATERIAL7;

implementation

type

  TSXTLVertexMT = packed record

    case Integer of

      0: (

        x, y, z, rhw: Single; //頂点

        diffuse: TD3DCOLOR; //ディフューズ

        specular: TD3DCOLOR; //スペキュラ

        tu0, tv0: Single; //テクスチャ座標

        tu1, tv1: Single; //テクスチャ座標2

        );

      1: (

        pos: TD3DVector;

        );

      2: (

        hgPos: TD3DHVector;

        );

  end;

const

  FVF_SXTLVertexMT: DWord = (D3DFVF_XYZRHW or D3DFVF_DIFFUSE or D3DFVF_SPECULAR or D3DFVF_TEX2);

{ Helper functions }

function SXVertex(x, y, z, nx, ny, nz: Single; dif, spec: TD3DCOLOR; tu, tv: Single): TSXVertex;

begin

  result.x := x;

  result.y := y;

  result.z := z;

  result.nx := nx;

  result.ny := ny;

  result.nz := nz;

  result.diffuse := dif;

  result.specular := spec;

  result.tu := tu;

  result.tv := tv;

end;

function SXVertexBB(dx, dy: Single; col: TD3DCOLOR; tu, tv: Single): TSXVertexBB;

begin

  result.dx := dx;

  result.dy := dy;

  result.color := col;

  result.tu := tu;

  result.tv := tv;

end;

{ TSXMesh }

//コンストラクタ

//Constructor

constructor TSXMesh.Create(AOwner: TDXDraw);

begin

  inherited Create;

  FOwner := AOwner;

  FVBuf := nil;

  SetLength(FIndices, 0);

  FIndexCount := 0;

  FFaceCount := 0;

  FVertexCount := 0;

  VertexKeepBuf := nil;

  FVertexSize := sizeof(TSXVertex);

  FVFFlags := FVF_SXVERTEX;

  FLocked := False;

  FRecovery := False;

end;

//デストラクタ

//Destructor

destructor TSXMesh.Destroy;

begin

  if FVBuf <> nil then

    FVBuf := nil; //._Release;

  if VertexKeepBuf <> nil then

    FreeMem(VertexKeepBuf);

  FIndices := nil;

  inherited;

end;

//現在のVertexBufferの状態を保持

//Currently holds the state of VertexBuffer

procedure TSXMesh.KeepVB;

begin

  if FVBuf <> nil then

  begin

    //バッファサイズの変更

    //Resizing of the buffer

    if VertexKeepBuf <> nil then

      FreeMem(VertexKeepBuf);

    VertexKeepBuf := AllocMem(VertexSize * FVertexCount);

    Self.Lock;

    Move(FPVertex^, VertexKeepBuf^, VertexSize * FVertexCount);

    Self.Unlock;

  end;

end;

//保存したVertexBufferの状態を復元

//Restore the state saved VertexBuffer

procedure TSXMesh.RecoverVB;

begin

  if FVBuf <> nil then

  begin

    //リカバリ期間・開始

    //Recovery period begins

    FRecovery := True;

    FVBuf := nil;

    SetSize(FVertexCount, FIndexCount);

    Self.Lock;

    Move(VertexKeepBuf^, FPVertex^, VertexSize * FVertexCount);

    Self.Unlock;

    FreeMem(VertexKeepBuf);

    VertexKeepBuf := nil;

    FRecovery := False;

    //リカバリ期間・終了

    //Recovery period ends

  end;

end;

//DPで描画

//Simple DP draw

procedure TSXMesh.Draw(dwFlags: DWord);

var

  ofs: Word;

  nIs: Word;

begin

  ofs := 0;

  while ofs < FIndexCount do

  begin

    nIs := FIndexCount - ofs;

    if nIs > DIV_VERTICES then

      nIs := DIV_VERTICES;

    FOwner.D3DDevice7.DrawIndexedPrimitiveVB(

      D3DPT_TRIANGLELIST, FVBuf, 0, FVertexCount, FIndices[ofs], nIs, dwFlags);

    Inc(ofs, nIs);

  end;

end;

//DPで描画

//Draw DP strem of primitives

procedure TSXMesh.DrawPartial(start: Word; count: Word; dwFlags: DWord);

begin

  FOwner.D3DDevice7.DrawIndexedPrimitiveVB(

    D3DPT_TRIANGLELIST, FVBuf, 0, FVertexCount, FIndices[start], count, dwFlags);

end;

//インデクス操作

//Check index

function TSXMesh.GetIndex(idx: Word): Word;

begin

  if idx >= FIndexCount then

  begin

    //DDDD_PutDebugMessage('SXLib: 範囲外の頂点インデクスを参照しようとしました');

    result := 0;

    exit;

  end;

  result := FIndices[idx];

end;

procedure TSXMesh.SetIndex(idx: Word; const Value: Word);

begin

  if idx >= FIndexCount then

  begin

    //DDDD_PutDebugMessage('SXLib: 範囲外の頂点インデクスを設定しようとしました');

    exit;

  end;

  FIndices[idx] := Value;

end;

//頂点操作

//Operation on Vertex

function TSXMesh.GetVertex(idx: Word): Pointer;

var

  pV: Pointer;

  ofs: DWord;

  lpdwSize: Cardinal;

begin

  //範囲チェック

  //check range

  if idx >= FVertexCount then

  begin

    //DDDD_PutDebugMessage('SXLib: 範囲外の頂点を参照しようとしました');

    result := nil;

    exit;

  end;

  //ロックされていないなら、ロック。ロックされてるなら、前に得たポインタをゲット

  //when is unlocked, then lock there

  if not FLocked then

  begin

    if FVBuf.Lock(DDLOCK_READONLY or DDLOCK_WAIT, pV, lpdwSize) <> DD_OK then

    begin

      //DDDD_PutDebugMessage('SXLib: VertexBufferがロックできません');

      Halt;

    end;

  end

  else

    pV := FPVertex;

  //返り値に格納

  //calc place of vertices

  ofs := idx * VertexSize;

  asm

    mov   eax,ofs;

    add   pV,eax;

  end;

  result := pV;

  //アンロック

  //unlock

  if not FLocked then

  begin

    if FVBuf.Unlock <> DD_OK then

    begin

      //DDDD_PutDebugMessage('SXLib: VertexBufferがアンロックできません');

      Halt;